: INSERT  Insert Specified Disk into Floppy Drive  06/11/1994-10/15/1999
: ----------------------------------------------------------------------
: Copyright (C) 1994-1999 by Vladimir Veytsel              www.davar.net

: 1. Disk drive letter (no ":")
:    "?"  - Display <name> batch command text (Equivalent: "/")
: 2. Floppy disk name
: 3. Bypass specified actions:
:    I  - Bypass initial request
:    N  - Bypass disk name checking

:    Notes:

:     - Returns "0" in "%?" for successful insert and "1" otherwise
:     - Empty value of S environment variable suppresses beep sound
:       (See S.BTM for details about S environment variable)

:    Example of usage: "CALL INSERT A,W-JOB,I || QUIT"

@ECHO %TR%

 IF %1.==/. .OR. %1.==?. (LIST %_BATCHNAME ^ QUIT)

 IF %@INDEX[%@UPPER[%3],I] GE 0 GOTO Check

:Beep

 IF NOT %S%.==. BEEP 440 4 587 2 1040 6

:Ins

 SET Ins=
 INKEY /K"[Enter] [Esc]" %W%Insert %G%%@UPPER[%2] %W%disk into floppy drive %G%%@UPPER[%1]: %W%and hit %C%[Enter]%D% %%Ins
 IF "%Ins%" NE "@28" (SET Ins= ^ QUIT 1)
 SET Ins=

:Check

 IFF %@READY[%@UPPER[%1]:].==0. THEN
     ECHO:
     ECHO %R%No disk is inserted into drive %M%%@UPPER[%1]:%D%
     GOTO Beep
 ENDIFF

 IF %@INDEX[%@UPPER[%3],N] GE 0 .OR. %@LABEL[%@UPPER[%1]:].==%@UPPER[%2]. (SET INS= ^ QUIT 0)
 ECHO:
 ECHO %R%Wrong disk %M%%@LABEL[%@UPPER[%1]:] %R%is inserted instead of requested %M%%@UPPER[%2]%D%
 GOTO Beep